Lessons · Advanced

Silent anchors & sequences

A figure counted from a note that never sounds

% Bach's Little Fugue reaches an episode (m.59) on one figure walked
% down the scale: seven notes, the same seven a step lower, then lower
% again, and before the second and third statements a CONNECTIVE note,
% bb then a, stepping down with them. Written as intervals from that
% note the figure owns no pitch of its own, and anchor application
% stamps it once per anchor, as the assert spells:
 
bpm 100
instrument plain
meter 4
unit 1/4
key g4 min
 
Q ::= s4 s-1 s-1 s5 s-2 s-2 s2
 
assert Q(.3 .2) == .3 Q .2 Q
 
.3 Q .2 Q .1 _6
 
 
% The first statement comes in under a high c, the last note of the
% phrase before, an octave too high for the figure to count from. A
% SILENT ANCHOR '!' sets the note relatives count from WITHOUT sounding
% it: '!.4' puts the thread on the c below, Q counts from there, and
% the high c keeps its place in the music. That is the episode as Bach
% wrote it, and the assert states the same seven notes the plain way:
 
assert !.4 Q == 1 .7 .6 4 2 .7 2
 
4 !.4 Q Q(.3 .2) {3, .1} {5, .3} {4, .5} {3, 1} {2, .7} {3, 1} {1, .7b} {2, .7}
1 _6 .7# _2 1 _8
 
 
% Silent anchors stamp too. 'Q(!.4 !.3 !.2)' is the three statements
% with no connective sounding at all (the figure alone, walking), and
% a degree, a note name or a relative step can all be anchors ('!4',
% '!c4', '!s-1'). A mark after the ')' covers the whole run:
 
assert Q(!.4 !.3 !.2) == !.4 Q !.3 Q !.2 Q
 
Q(!.4 !.3 !.2)
Q(!.4 !.3 !.2)@~4 Q(!.4 !.3 !.2)@~2 .1 _8
 
 
% With no connective the figure walks by ITSELF. Mozart's K 545 (m.5)
% runs one scale figure three times, each a step lower. Written from
% the note it starts on ('s0' is that note), and closed with a silent
% step, '!s-1', every copy leaves the thread one step below where it
% began; so '*3' IS the sequence, from one silent anchor, and the assert
% shows it against the figure spelled in degrees and moved by '@~':
 
bpm 132
key c4 maj
 
Run  ::= s0 _2 s1 s1 s1 s1 s1 s1 s1 s-1 s-1 s-1 s-1 s-1 s-1 s-1 !s-1
Rise ::= 6 _2 7 '1 '2 '3 '4 '5 '6 '5 '4 '3 '2 '1 7 6
 
assert !6 Run *3 == Rise Rise@~-1 Rise@~-2
 
!6 Run *3 5Maj _2 1Maj _2
 
 
% The walk over its harmony (vi, ii, V, one chord a measure, the way
% the left hand holds under Mozart's right), and then the same walk
% started a third higher, which the silent anchor alone decides:
 
{!6 Run *3, {.6, 1, 3} _16 {.2, .4, .6} _16 {.5, .7, 2} _16} 1Maj _4
{!'1 Run *3, {1, 3, 5} _16 {.4, .6, 1} _16 {.5, .7, 2} _16} 1Maj _4
 
 
% In a RULE BODY the paren must hug the name: 'Q(.3 .2)' is an
% application, 'Q (a = b)' with a space is a group of alternatives, as
% it always was. So each passage is one rule that reads as the music
% (the episode with its silent first anchor, the walk from its anchor),
% and the piece states them:
 
key g4 min
Episode ::= 4 !.4 Q Q(.3 .2) {3, .1} {5, .3} {4, .5} {3, 1} {2, .7} {3, 1} {1, .7b} {2, .7} 1 _6 .7# _2 1 _8
key c4 maj
Walk    ::= !6 Run *3 5Maj _2 1Maj _2
 
key g4 min
Episode
key c4 maj
Walk
{!6 Run *3, {.6, 1, 3} _16 {.2, .4, .6} _16 {.5, .7, 2} _16} 1Maj _4

% Bach's Little Fugue reaches an episode (m.59) on one figure walked
% down the scale: seven notes, the same seven a step lower, then lower
% again, and before the second and third statements a CONNECTIVE note,
% bb then a, stepping down with them. Written as intervals from that
% note the figure owns no pitch of its own, and anchor application
% stamps it once per anchor, as the assert spells:

bpm 100
instrument plain
meter 4
unit 1/4
key g4 min

Q ::= s4 s-1 s-1 s5 s-2 s-2 s2

assert Q(.3 .2) == .3 Q .2 Q

.3 Q .2 Q .1 _6

% The first statement comes in under a high c, the last note of the
% phrase before, an octave too high for the figure to count from. A
% SILENT ANCHOR '!' sets the note relatives count from WITHOUT sounding
% it: '!.4' puts the thread on the c below, Q counts from there, and
% the high c keeps its place in the music. That is the episode as Bach
% wrote it, and the assert states the same seven notes the plain way:

assert !.4 Q == 1 .7 .6 4 2 .7 2

4 !.4 Q Q(.3 .2) {3, .1} {5, .3} {4, .5} {3, 1} {2, .7} {3, 1} {1, .7b} {2, .7}
1 _6 .7# _2 1 _8

% Silent anchors stamp too. 'Q(!.4 !.3 !.2)' is the three statements
% with no connective sounding at all (the figure alone, walking), and
% a degree, a note name or a relative step can all be anchors ('!4',
% '!c4', '!s-1'). A mark after the ')' covers the whole run:

assert Q(!.4 !.3 !.2) == !.4 Q !.3 Q !.2 Q

Q(!.4 !.3 !.2)
Q(!.4 !.3 !.2)@~4 Q(!.4 !.3 !.2)@~2 .1 _8

% With no connective the figure walks by ITSELF. Mozart's K 545 (m.5)
% runs one scale figure three times, each a step lower. Written from
% the note it starts on ('s0' is that note), and closed with a silent
% step, '!s-1', every copy leaves the thread one step below where it
% began; so '*3' IS the sequence, from one silent anchor, and the assert
% shows it against the figure spelled in degrees and moved by '@~':

bpm 132
key c4 maj

Run  ::= s0 _2 s1 s1 s1 s1 s1 s1 s1 s-1 s-1 s-1 s-1 s-1 s-1 s-1 !s-1
Rise ::= 6 _2 7 '1 '2 '3 '4 '5 '6 '5 '4 '3 '2 '1 7 6

assert !6 Run *3 == Rise Rise@~-1 Rise@~-2

!6 Run *3 5Maj _2 1Maj _2

% The walk over its harmony (vi, ii, V, one chord a measure, the way
% the left hand holds under Mozart's right), and then the same walk
% started a third higher, which the silent anchor alone decides:

{!6 Run *3, {.6, 1, 3} _16 {.2, .4, .6} _16 {.5, .7, 2} _16} 1Maj _4
{!'1 Run *3, {1, 3, 5} _16 {.4, .6, 1} _16 {.5, .7, 2} _16} 1Maj _4

% In a RULE BODY the paren must hug the name: 'Q(.3 .2)' is an
% application, 'Q (a = b)' with a space is a group of alternatives, as
% it always was. So each passage is one rule that reads as the music
% (the episode with its silent first anchor, the walk from its anchor),
% and the piece states them:

key g4 min
Episode ::= 4 !.4 Q Q(.3 .2) {3, .1} {5, .3} {4, .5} {3, 1} {2, .7} {3, 1} {1, .7b} {2, .7} 1 _6 .7# _2 1 _8
key c4 maj
Walk    ::= !6 Run *3 5Maj _2 1Maj _2

key g4 min
Episode
key c4 maj
Walk
{!6 Run *3, {.6, 1, 3} _16 {.2, .4, .6} _16 {.5, .7, 2} _16} 1Maj _4

running…edit it and it re-runs as you type

Silent anchors & sequences · Advanced